Question Locked

How to set default printer for a user in a domain environment?

0 helpful
4 replies
Closed to new repliesThis discussion is closed. It stays readable, but it takes no new replies.

I have several PC running Win XP in a domain environment.There is a user called 'oper' which normally users use to login in the XP machines.

I need to set default printer for 'oper' in all the PCs from a single machine.Is there any vbscript or command to configure default printer on all PCs remotely so that the users are not disturbed?

4 replies

by shane

In VB Script:

Dim onet

Set onet = CreateObject("WScript.Network")

onet.AddWindowsPrinterConnection "\\server\printershare", "HP LaserJet 2100"

onet.SetDefaultPrinter "\\server\printershare"

by abhilash_ponoli

shane, thank u for the reply.

How can I run this script on all the Winxp machines remotely.I dont want to disturb the users.

by cg it

here ya go this is for setting the default printer by IP address

strComputer = "."

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")

Set colItems = objWMIService.ExecQuery _
("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled = True")

For Each objItem in colItems
strIPAddress = objItem.IPAddress(0)
arrIPAddress = Split(strIPAddress, ".")

If arrIPAddress(0) = "192" Then

Select Case arrIPAddress(1)
Case 1
Set colInstalledPrinters = objWMIService.ExecQuery _
("Select * from Win32_Printer Where Name = '\\\\atl-ps-01\\printer1'")
For Each objPrinter in colInstalledPrinters
objPrinter.SetDefaultPrinter()
Exit For
Next
Case 2
Set colInstalledPrinters = objWMIService.ExecQuery _
("Select * from Win32_Printer Where Name = '\\\\atl-ps-01\\printer2'")
For Each objPrinter in colInstalledPrinters
objPrinter.SetDefaultPrinter()
Exit For
Next
End Select
End If
Next

uou can do this by OU as well.

Set objSysInfo = CreateObject("ADSystemInfo")
strName = objSysInfo.ComputerName

arrComputerName = Split(strName, ",")
arrOU = Split(arrComputerName(1), "=")
strComputerOU = arrOU(1)

Set objNetwork = CreateObject("WScript.Network")

Select Case strComputerOU
Case "Client"
objNetwork.AddWindowsPrinterConnection "\\PrintServer1\ClientPrinter"
objNetwork.SetDefaultPrinter "\\PrintServer1\ClientPrinter"
Case "Finance"
objNetwork.AddWindowsPrinterConnection "\\PrintServer2\FinancePrinter"
objNetwork.SetDefaultPrinter "\\PrintServer2\FinancePrinter"
Case "Human Resources"
objNetwork.AddWindowsPrinterConnection "\\PrintServer3\HRPrinter"
objNetwork.SetDefaultPrinter "\\PrintServer3\HRPrinter"
Case "Research"
objNetwork.AddWindowsPrinterConnection "\\PrintServer4\ResearchPrinter"
objNetwork.SetDefaultPrinter "\\PrintServer4\ResearchPrinter"
Case Else
objNetwork.AddWindowsPrinterConnection "\\PrintServer5\GenericPrinter"
objNetwork.SetDefaultPrinter "\\PrintServer5\GenericPrinter"
End Select

These scripts are right from "Hey Scripting Guy" on the microsoft Technet site.. http"//www.microsoft.com/technet/scriptcenter

This discussion is closed to new replies.