Discussion Locked

A Halloween prezzy for those admins with a malicious disposition

0 helpful
3 replies
Closed to new repliesThis discussion is closed. It stays readable, but it takes no new replies.

Copy the bit between the dashed lines (NOT including the lines) into Notepad and save as "halloween.vbs". Get a suitable horror bitmap (bmp) file showing the picture that you want [b]at a suitable resolution[/b]. Get a wav file for a scream or whatever. Copy both into c:\windows on your target's PC (and your own for testing). Edit Halloween.vbs to set a suitable time delay after login or startup (line 7), change the bitmap name (line 24) and the wav name (line 38) to suit your files and set how long you want the change to stay up (line 45).

Note, XP only as I have avoided having to use Vista so far.

Test on your PC! Copy Halloween.vbs to the target PC C:\Documents and Settings\All Users\Start Menu\Programs\Startup.

Ooops! Edit to actually tell you what it does. At your pre-set interval after the victim user has logged in, the program will shrink all windows, hide all icons and set the users wallpaper to your HORROR version and play a wav file (the most effective that I have found is an exploding monitor screen accompanied by a loud bang). After your pre-set time, the desktop is replaced exactly as it was.

-------------------------------------
Set oShell = CreateObject("WScript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
set oDesktop=CreateObject("Shell.Application")

' Set the value to the number of msecs that you want to wait. i.e. 300000 is five minutes

wscript.sleep 300000

' OK, now DO IT!

' Minimise all of the working windows for full effect

oDesktop.MinimizeAll

' Get and save the old wallpaper

sOldWallpaper = oShell.RegRead("HKCU\Control Panel\Desktop\Wallpaper")

' New wallpaper. This should be a bitmap (.bmp) of a suitable resolution
' Copy the bmp to C:\Windows
' Replace the filename with your gruesome bitmap

sWinDir = oFSO.GetSpecialFolder(0)
sWallPaper = sWinDir & "\sky.bmp"

' Update in registry

oShell.RegWrite "HKCU\Control Panel\Desktop\Wallpaper", sWallPaper

' Let the system know about the change

sCommand = _
"%windir%\System32\RUNDLL32.EXE user32.dll,UpdatePerUserSystemParameters"
oShell.Run sCommand,1,True

' Play a sound
' Copy a scream or whatever wav file into C:\Windows

sSoundFile = sWinDir & "\tada.wav"

sCommand = "sndrec32 /play /close " & chr(34) & sSoundFile & chr(34)
oShell.Run sCommand, 0, False

' Time to display the Halloween wallpaper in ms

wscript.sleep 10000

' Put it back - Update in registry

oShell.RegWrite "HKCU\Control Panel\Desktop\Wallpaper", sOldWallPaper

sCommand = _
"%windir%\System32\RUNDLL32.EXE user32.dll,UpdatePerUserSystemParameters"
oShell.Run sCommand,1,True

' Put the Windows back

oDesktop.UndoMinimizeAll
---------------------------------------

Neil ]:)

3 replies

by jaqui

gonna have fun tonight ]:)
[ there ain't no-one but me in the office tonight, and there is one windows system, someone's private system ]

by tig2

You would have to post this after I got on my partner to change his BIOS password!

Now I'm going to have to wait until he steps away from his computer to set this up! At least I can get everything ready.

Exploding monitor. Hmmm. Must Google.

This should be fun!
Thanks, Neil!
:x

by jaqui

adding the user's app list to that all user startup.
every app installed starts when they turn the system on on Halloween morning, then the system shuts itself down with a howling in pain. ]:)

A friend played with it and made his windows do that.

This discussion is closed to new replies.